From Microsoft Visio to MetaEdit+ via Eclipse EMF

rule Document2Project
	transform document : Visio!EVisioDocument
  	to project : MetaEdit!Me_Project
  	{
  		project.me_containGraphs := document.visioPages.equivalent();
  		project.me_containObjects := MetaEdit!Me_Object.allInstances();
  		project.me_containRelationships := MetaEdit!Me_Relationship.allInstances();
  		project.me_containRoles := MetaEdit!Me_Role.allInstances();
  	}
 
@abstract
rule Page2Graph
	transform page : Visio!EVisioPage
	to graph : MetaEdit!Me_Graph
	{
		var diagram := new MetaEdit!Me_Diagram;
		graph.me_containDiagrams.add(diagram);
 
		var simpleShapes := page.visioContainedShapes->select(e | not e.isKindOf(Visio!EVisioConnectionShape));
		graph.me_referenceObjects := simpleShapes.equivalent();
		for (shape : Visio!EVisioShape in simpleShapes) {
			var symbol := new MetaEdit!Me_Symbol;
			diagram.me_containSymbols.add(symbol);
			symbol.me_refObject := shape.equivalent();
			symbol.me_position := shape.getPinX()+','+shape.getPinY();
		}
 
		var conShapes := page.visioContainedShapes->select(e | e.isKindOf(Visio!EVisioConnectionShape));
		graph.me_referenceRelationships := conShapes.equivalent().select(e | e.isKindOf(MetaEdit!Me_Relationship));
		graph.me_referenceRoles := conShapes.equivalent().select(e | e.isKindOf(MetaEdit!Me_Role));
 
	}	
 
operation Visio!EVisioShape getPinX() : Integer {
	return self.visioShapeSheet
		.visioSections.select(e | e.visioName = 'visSectionObject').first()
		.visioRows.select(e | e.visioName = '1').first()
		.visioCells.select(e | e.visioName = 'PinX').first()
		.visioValue.asReal();
}
 
operation Visio!EVisioShape getPinY() : Integer {
	return self.visioShapeSheet
		.visioSections.select(e | e.visioName = 'visSectionObject').first()
		.visioRows.select(e | e.visioName = '1').first()
		.visioCells.select(e | e.visioName = 'PinY').first()
		.visioValue.asReal();
}
 
post CoordinateTransformation {
 
	var ymax : Real := MetaEdit!Me_Symbol.allInstances.sortBy(e|e.me_position.split(',').last())
		.last().me_position.split(',').last().asReal();
 
	for (symbol : MetaEdit!Me_Symbol in MetaEdit!Me_Symbol.allInstances) {
		var x : Real := symbol.me_position.split(',').first().asReal();
		var y : Real := symbol.me_position.split(',').last().asReal();
 
		x := x*100;
		y := (ymax*120+20)-y*100;
 
		symbol.me_position := x.asInteger() + ',' + y.asInteger();
	}
}

---------------------
-- EPC-Transformation
---------------------
rule VisioEpc2MetaEditEpc
	transform page : Visio!EVisioPage
	to graph : MetaEdit!Event_Driven_Process_Chain_3395083925
	extends Page2Graph
	{
		graph.Name := page.visioName;
	}
 
rule VisioEvent2MetaEditEvent
	transform shape : Visio!Ereignis
	to object : MetaEdit!Event_3395083771
	{
		object.Name := shape.visioText;
	}
 
rule VisioFunction2MetaEditFunction
	transform shape : Visio!Funktion
	to object : MetaEdit!Function_3395083784
	{
		object.Name := shape.visioText;
	}
 
rule VisioXOR2MetaEditXOR
	transform shape : Visio!XOR
	to object : MetaEdit!XOR_3395083733 {}
 
rule VisioOR2MetaEditOR
	transform shape : Visio!OR
	to object : MetaEdit!OR_3395083742 {}
 
rule VisioAND2MetaEditAND
	transform shape : Visio!AND
	to object : MetaEdit!AND_3395083748 {}
 
rule VisioConnection2MetaEditArc
	transform shape : Visio!Dynamischer_Verbinder
	to relation : MetaEdit!Arc_3395083800,
	fromRole : MetaEdit!From_3395083804,
	toRole : MetaEdit!To_3395083810
	{
		relation.me_role.add(fromRole);
		relation.me_role.add(toRole);
		fromRole.me_object := shape.visioSourceShape.equivalent();
		toRole.me_object := shape.visioTargetShape.equivalent();
	}